セル内グラフ　スプレッドシート

Kくん

スプレッドシートでセル内にグラフを表示する機能ってできないのかな。

ママ

あるわよ。スプレッドシートでは関数を使用することでできるわよ。

よく使いそうなことを中心に紹介するわね。

SPARKLINE関数は、Excelでも使えるのか。
SPARKLINE関数でどのようなグラフが作成できるのか。

SPARKLINE関数は、Excelでも使えるのか。

SPARKLINE関数は、現在Excelには、存在しない関数になります。Excelは関数と違う方法で、SPARKLINEを作成することができます。

今回はスプレッドシートのSPARKLINE関数について紹介していきます。

SPARKLINE関数でどのようなグラフが作成できるのか。

Google ドキュメントエディタヘルプを参考にしてます。

SPARKLINE関数には、４種類のグラフを作成することができ、”charttype”でグラフの種類を変更することができます。

"line" – 折れ線グラフ（デフォルト）
"bar" – 積み重ね棒グラフ
"column" – 縦棒グラフ
"winloss" – 正と負（コイン投げの表と裏など）の 2 つの結果を表す縦棒グラフ

=SPARKLINE(B3:E3)
=SPARKLINE(B4:E4,{"charttype","line"})
=SPARKLINE(B5:E5,{"charttype","bar"})
=SPARKLINE(B6:E6,{"charttype","column"})
=SPARKLINE(B7:E7,{"charttype","winloss"})

line：折れ線グラフ（デフォルト）

グラフの色や太さは変更できるのか。

色もグラフの太さも変更ができます。

グラフの色：”color”

グラフの色は色の名前（例: 「green」）または 16 進数コード（例: 「#3D3D3D」）で指定できます。

色について調べたい場合は、WEB色見本大辞典が参考になります。

グラフの太さ：”linewidth”

数字が大きくなるほど、グラフの線が太くなります。

=SPARKLINE(B4:E4)
=SPARKLINE(B5:E5,{"color","red"})
=SPARKLINE(B6:E6,{"color","red";"linewidth",5})
=SPARKLINE(B6:E6,{"color","red";"linewidth",10})

bar：積み重ね棒グラフ

すべて同じ長さのグラフになり比較できません。なぜでしょうか。

オプションで”max”値を指定していないためです。（”max” は横軸の最大値です。）

数値を比較するグラフを作成する場合は、必ず”max”を指定してください。

“max”の値は、セル番号でも指定できるようです。

例）SPARKLINE(B5,{“charttype”,”bar”;”max”,E5})

=SPARKLINE(B3,{"charttype","bar"})
=SPARKLINE(B4,{"charttype","bar"})
=SPARKLINE(B5,{"charttype","bar";"max",500000})
=SPARKLINE(B6,{"charttype","bar";"max",500000})

棒グラフを積み上げる方法を教えてほしい。

積み上げる値をすべて選択することができます。

=SPARKLINE(B4:E4,{"charttype","bar";"max",1500000})
=SPARKLINE(B5:E5,{"charttype","bar";"max",1500000})
=SPARKLINE(B6:E6,{"charttype","bar";"max",1500000})

棒グラフを積み上げるとき、一番大きい合計値をMAX値にしたい。

max関数を使えばできます。

=SPARKLINE(B4:E4,{"charttype","bar";"max",max($F$4:$F$6)})
=SPARKLINE(B5:E5,{"charttype","bar";"max",max($F$4:$F$6)})
=SPARKLINE(B6:E6,{"charttype","bar";"max",max($F$4:$F$6)})

棒グラフの色を変更することはできるのか。

2色まで棒グラフの色を変更することができます。

“color1″と”color2″で指定できます。”color3″としても３番目も色は変わりません。

“color1″と”color2″を指定しない場合は、オレンジ、水色のような色で表示されます。

色については、WEB色見本大辞典を参考。

=SPARKLINE(B4:E4,{"charttype","bar";"max",1500000})
=SPARKLINE(B5:E5,{"charttype","bar";"max",1500000;"color1","hotpink"})
=SPARKLINE(B6:E6,{"charttype","bar";"max",1500000;"color2","#000080"})
=SPARKLINE(B7:E7,{"charttype","bar";"max",1500000;"color1","#fffacd";"color2","#F10050"})

column：縦棒グラフ

縦棒グラフの色を変更したい。

“color” ：すべての縦棒の色を変更。
“lowcolor”：グラフ内の最小値の色を変更。
“highcolor”：グラフ内の最大値の色を変更。
“firstcolor” ：最初の縦棒の色を変更。
“lastcolor” ：最後の縦棒の色を変更。
“negcolor” ：すべての負の縦棒の色を変更。

=SPARKLINE(B4:E4,{"charttype","column"})
=SPARKLINE(B5:E5,{"charttype","column";"color","green"})
=SPARKLINE(B6:E6,{"charttype","column";"lowcolor","red"})
=SPARKLINE(B7:E7,{"charttype","column";"highcolor","blue"})
=SPARKLINE(B8:E8,{"charttype","column";"lowcolor","red";"highcolor","blue"})
=SPARKLINE(B9:E9,{"charttype","column";"color","green";"lowcolor","red";"highcolor","blue"})
=SPARKLINE(B10:E10,{"charttype","column";"firstcolor","green";"lastcolor","red"})
=SPARKLINE(B11:E11,{"charttype","column";"negcolor","red"})

縦棒グラフにしたい表に空白や文字が入っていた場合どうなるのか。

表に空白があった場合は、グラフに反映されません。反映させてい場合は、”empty”,”zero”を指定することで「0」と同様のグラフになります。

表に文字が入力されていた場合は、グラフに反映されません。反映させてい場合は、”nan”,”convert”を指定します。

SPARKLINE(B4:E4,{"charttype","column"})
SPARKLINE(B5:E5,{"charttype","column"})
SPARKLINE(B6:E6,{"charttype","column"})
SPARKLINE(B7:E7,{"charttype","column";"empty","zero"})
SPARKLINE(B8:E8,{"charttype","column"})
SPARKLINE(B9:E9,{"charttype","column";"nan","convert"})

プラスとマイナスの境目の軸を表示したい

“axis”で指定することができ、”axiscolor”で色を変更することもできます。

SPARKLINE(B4:E4,{"charttype","column"})
SPARKLINE(B5:E5, {"charttype","column"; "axis", true})
SPARKLINE(B6:E6, {"charttype","column"; "axis", true; "axiscolor", "red"})